pxJSetPulleyLocalAttachBody(joint%, x1#, y1#, z1#, x2#, y2#, z2#)

Параметры

joint% - соединение
x1#, y1#, z1# - вектор оси первого тела
x2#, y2#, z2# - вектор оси второго тела

Описание

Устанавливает вектор для осей весов.

Смотрите так же

Пример

;Пример применения функции
;pxJSetPulleyLocalAttachBody

;В данном примере нам понадобятся несколько однотипных тел
Type Px_Cube
    Field body%
    Field mesh%
End Type

Graphics3D 800, 600, 32, 2
SetBuffer BackBuffer()

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()

PositionEntity camera,0,40,-20
RotateEntity camera,30,0,0

plane=CreatePlane() ;Визуализируем поверхность
EntityColor plane,0,100,200
EntityAlpha plane,0.5

mir = CreateMirror () ;Чуть украсим зеркалом

mesh = LoadMesh ("media\Tarelka.3ds")
ScaleMesh mesh,0.2,0.2,0.2
PositionEntity mesh,0,30,0
initial_mesh = BodyCreateMesh%(mesh,"media\tarelka.pm")
HideEntity mesh

tarelka1_mesh=CopyMesh(mesh)
tarelka1_body=pxCreateTriMesh(initial_mesh,10)
pxSetPosition(tarelka1_body,10,30,0)

tarelka2_mesh=CopyMesh(mesh)
tarelka2_body=pxCreateTriMesh(initial_mesh,10)
pxSetPosition(tarelka2_body,-10,30,0)

;Создаем весы
joint = pxJCreatePulley(tarelka1_body, tarelka2_body, 5, 1, 1)
;Задаем начальную позицию чаш весов
pxJSetPulleyAnchor(joint, 10,40,0, -10,40,0)
;Устанавливаем вектор движения весов по Y
; ------------ Применяем pxJSetPulleyLocalAttachBody:
pxJSetPulleyLocalAttachBody(joint, 0,1,0, 0,1,0)

;Основной цикл программы
While Not KeyDown(1) ;Пока не нажат ESC

    If KeyHit(2) ;Добавим кубик слева
        ocu.Px_Cube = New Px_Cube
        ocu\mesh=CreateCube ()
        ocu\body=PxCreateCube(1,1,1, 1)
        pxSetPosition(ocu\body,-10+Rand(-2,2),40,Rand(-3,3))
    EndIf

    If KeyHit(3) ;Добавим кубик справа
        ocu.Px_Cube = New Px_Cube
        ocu\mesh=CreateCube()
        ocu\body=PxCreateCube(1,1,1, 1)
        pxSetPosition(ocu\body,10-Rand(-2,2),40,Rand(-3,3))
    EndIf

;обсчитываем физический мир
    RenderPhysic(60,0)

;Обновим положения всех объектов
    For ocu.Px_Cube = Each Px_Cube
     pxSetEntity(ocu\mesh, ocu\body)
    Next
;и весов
    pxSetEntity(tarelka1_mesh,tarelka1_body)
    pxSetEntity(tarelka2_mesh,tarelka2_body)

    RenderWorld
    Text 10,10, "1 - Добавить слева кубик"
    Text 10,20, "2 - Добавить справа кубик"
    Flip
    Wend
End

Function BodyCreateMesh(mesh%,file_name$)

    nsurf = CountSurfaces(mesh)
    nvert = 0
    nface = 0
    For ns = 1 To nsurf
        Local surf = GetSurface(mesh,ns)
        nface = nface+CountTriangles(surf)
        nvert = nvert +CountVertices(surf)
    Next

    fbank = CreateBank(nface*4*3)
    nf = 0
    vbank = CreateBank(nvert*4*3)
    nv = 0
    For ns = 1 To nsurf
        surf = GetSurface(mesh,ns)
        nfv = CountTriangles(surf)
        For nfc = 0 To nfv -1
            PokeInt fbank,nf*12+0,TriangleVertex(surf,nfc,0)
            PokeInt fbank,nf*12+4,TriangleVertex(surf,nfc,1)
            PokeInt fbank,nf*12+8,TriangleVertex(surf,nfc,2)
            nf=nf+1
        Next

        nvv = CountVertices(surf)
        For nvc = 0 To nvv - 1
            PokeFloat vbank,nv*12+0,VertexX(surf,nvc)
            PokeFloat vbank,nv*12+4,VertexY(surf,nvc)
            PokeFloat vbank,nv*12+8,VertexZ(surf,nvc)
            nv = nv+1
        Next
    Next
    bbb%=pxInitTriMesh(vbank, fbank, nvert, nface, file_name$)
    FreeBank vbank
    FreeBank fbank
    Return bbb%
End Function

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.